Useless Machine met Leeuw

Dit is een useless box op basis van een Arduino Nano.
In dit artikel leg ik uit hoe ik deze geweldige useless machine heb gemaakt.

Leeuw

Het kastje

Ik heb er voor gekozen om het kastje zelf te maken, je zou misschien ook een kant en klaar kastje kunnen kopen.
De CAD tekening voor het kastje kun je hier downloaden:
- Als PDF
- In autocad formaat (voor lasercutter of cnc router)

Het Schema

Het schema is niet ingewikkeld. Alle intelligentie zit natuurlijk in de software. De box heeft geen aan/uit schakelaar en is dus altijd klaar voor gebruik. En toch verbruikt hij geen batterij als hij uit staat. Hoe dat werkt, leg ik uit in de video
Tussen de Vin en GND op de arduino, zit een extra elco van 100uF/16Volt, in de video gebruik ik een 33uF maar die heb ik later vervangen voor 100uF. Dit is om storing tegen te gaan

Klik op het schema om het te vergroten

De Sketch

De sketch is nog een beetje rommelig, misschien dat ik hem ooit nog eens opnieuw schrijf maar voor nu is het wat het is.
Het werkt in ieder geval :-)

/*
Useless Machine 2 sketch
De leeuw in de kist

Bart Venneker 2016, https://www.bartvenneker.nl/Arduino/index.php?art=0023
*/

#include <Servo.h> 
#include <EEPROM.h>

#define doorClosed 130
#define doorOpen 80 
#define doorPeek 110
#define armIn 150
#define armOut 5
#define swtch 2
#define light A0

Servo klepServo;
Servo armServo;

unsigned long timeout = millis();
byte doorPos=doorClosed;
byte armPos=armIn;

void setup() {
  pinMode(light,OUTPUT);
  pinMode(swtch,INPUT_PULLUP);
  digitalWrite(light,LOW);
  klepServo.attach(9,3100,700);  
  armServo.attach(6,2700,544);
  delay(100);
  for (int x=0; x < 10; x++){
    armServo.write(armIn);
    klepServo.write(doorClosed);
    delay(50);
  }
  klepServo.detach();  
  armServo.detach();
}

 
void loop() {

  // Turn off after 30 seconds of no activity
  if (millis() - timeout > 30000) {
    armServo.detach();
    digitalWrite(light,HIGH);
    peek_1();
    // Move the doorServo to lowest position to press the microswitch and cut off the battery power
    for (int x=0; x < 10; x++){ klepServo.write(180);delay(50); }
  }

  if (!digitalRead(swtch)){  // If the switch is in the UP position ..
    
    timeout = millis();            // reset the timeout value
    digitalWrite(light,HIGH);      // light on
    int pn = EEPROM.read(0);       // read the eeprom to get the next routine
    klepServo.attach(9,3100,700);  // attach the servos
    armServo.attach(6,2700,544);
  
  switch (pn) {
    case 1: delay(500); routine_1(); EEPROM.write(0,2); break;
    case 2: delay(500); routine_2(); EEPROM.write(0,3); break;
    case 3: delay(500); routine_3(); EEPROM.write(0,4); break;
    case 4: delay(500); routine_4(); EEPROM.write(0,5); break;
    case 5: delay(500); routine_5(); EEPROM.write(0,6); break;
    case 6: delay(500); routine_6(); EEPROM.write(0,7); break;
    case 7: delay(500); routine_7(); EEPROM.write(0,8); break;
    case 8: delay(500); routine_8(); EEPROM.write(0,9); break;
    case 9: delay(500); routine_9(); EEPROM.write(0,1); break;
    default:EEPROM.write(0,1); break;
  }
  
  klepServo.detach();       // detach the servos
  armServo.detach(); 
  digitalWrite(light,LOW);  // lights out
  }
}


void setDoor(byte pos, byte speedDelay){
  if (pos > doorPos) {
    for (int p = doorPos; p < pos ; p++){
      klepServo.write(p);
      delay(speedDelay);
      }
    }
  else {
    for (int p = doorPos; p > pos ; p--){
      klepServo.write(p);
      delay(speedDelay);
      }
    }
    doorPos = pos;    
}

void setArm (byte pos, byte speedDelay) {
  if (pos > armPos){
    for (int p = armPos; p < pos ;){      
      p=p+5;
      armServo.write(p);
      delay(speedDelay);
      }
    }
    else {
      for (int p = armPos; p > pos ;){      
      p=p-5;
      armServo.write(p);
      delay(speedDelay);
      }

      }
      armPos = pos;
}

void peek_1(){
   klepServo.attach(9,3100,700);
   setDoor(doorPeek-20, 20);
   delay(2000);
   setDoor(doorClosed, 10);
  }

void flipSwitchSlow(int spDelay){ // 25 is slow, 50 or 100 is even slower
  byte p = armPos;
  while (!digitalRead(swtch)){
    p = p - 5;
    armServo.write(p);
    delay(spDelay);
    }
  armPos=p;  
  setArm(armIn,spDelay);      
  armPos=armIn;
  }

void flipSwitchFast(){
  for (byte x=0; x< 15; x++) {
     armServo.write(1);     
     delay(50);
     if (digitalRead(swtch)) break;
    }
    
  for (byte x=0; x< 15; x++) {
     armServo.write(armIn);
     delay(50);
    }    
    armPos = armIn;
  }

void doorOpenFast(){
  for (byte x=0; x< 10; x++) {
     klepServo.write(doorOpen);     
     delay(25);
    }
    doorPos = doorOpen; 
  }

void doorCloseFast(){
  for (byte x=0; x< 10; x++) {
     klepServo.write(doorClosed);     
     delay(25);
    }
  doorPos = doorClosed; 
  }
  
void klepper(){
  for (byte y=0 ; y<5 ; y++){
    for (byte x=0; x< 10; x++) {
      klepServo.write(doorPeek);     
      delay(15);
      }
    for (byte x=0; x< 10; x++) {
      klepServo.write(doorClosed);     
      delay(15);
      }    
  }
}

void setArmFast(byte pos, byte speedDelay){
  for (byte x=0; x< 10; x++) {
     armServo.write(pos);
     delay(speedDelay);
    }
    armPos = pos;
  };
 
void armPause(int d){
  armServo.detach(); 
  delay(d);     
  armServo.attach(6,2700,544);
  delay(100);
}
  
void routine_1(){
  // open the door,
  setDoor(doorOpen, 10);  
  flipSwitchSlow(50);
  setDoor(doorClosed, 10);
  armServo.detach();
  delay(2000); 
  // check!
  doorOpenFast();
  delay(1000);
  doorCloseFast();
  }

void routine_2(){
  doorOpenFast();
  flipSwitchFast();
  doorCloseFast();
}

void routine_3(){
  setDoor(doorOpen, 10);
  // flip the switch
  setArmFast(armOut,50);
  // hold the swich down for a moment
  armPause(1000);
  // lift the arm a bit 
  for (byte r=0; r< 2; r++){
    setArmFast(armOut+45,10);
    delay(250);
    setArmFast(armOut,10);
    delay(800);
  }
  armPause(1000);
  // arm back inside
  setArmFast(armIn,50);  
  doorCloseFast();   
   
  }

void routine_4(){
  routine_2();
  delay(700);
  check_3();
  }
  
void routine_5(){
  routine_2();
  delay(500);
  klepper();
  }

void routine_6(){
  setDoor(doorOpen, 50);
  setArm(armOut+30,50);
  delay(500);
  setArmFast(armOut,50);
  setArmFast(armOut+40,50);
  delay(500);
  setArmFast(armIn,50);
  doorCloseFast();
  routine_2();
  }
  
void routine_7(){
  doorOpenFast();
  delay(500);
  setArmFast(armOut+50,50);
  delay(100);
  doorCloseFast();
  delay(100);
  flipSwitchFast();  
  armPause(2000); check_2();
  }  

void routine_8(){
  setDoor(doorPeek, 10);
  delay(700);
  doorCloseFast();
  setDoor(doorPeek, 10);
  delay(1500);
  doorOpenFast();
  flipSwitchFast();
  doorCloseFast();
  armServo.detach();
  klepServo.detach();
  delay(1000);
  klepServo.attach(9,3100,700); 
  delay(100);
  setDoor(doorPeek-20, 10);
  delay(2000);
  doorCloseFast();  
  }

 void routine_9(){
  setDoor(doorOpen, 50);
  flipSwitchSlow(100);
  doorOpenFast();
  setArmFast(armOut,50);setArmFast(armOut+110,50);
  setArmFast(armOut,50);setArmFast(armOut+110,50);
  setArmFast(armOut,50);setArmFast(armIn,50);  
  doorCloseFast();
  }


void check_2(){
  doorOpenFast();
  setArmFast(armOut+70,50); 
  armPause(1500);
  setArmFast(armIn,50);  
  delay(100);
  doorCloseFast();
  }

void check_3(){
  doorOpenFast();
  setArmFast(armOut+70,50);
  armPause(1500);
  if (!digitalRead(swtch)) {routine_2();doorOpenFast();}
  setArmFast(armOut+110,50);
  delay(100);
  setArmFast(armOut+60,50);
  armPause(1500);
  if (!digitalRead(swtch)) {routine_2();}
  setArmFast(armIn,50);
  klepServo.attach(9,3100,700); 
  delay(100);
  doorCloseFast();
  }

Onderdelen

Hier is een lijst met de gebruikte onderdelen
De kosten zijn zijn berekend op daarwerkelijk verbruik, zo koop je bijvoorbeeld een plaat hout van 5 euro maar je gebruikt maar een kwart, de kosten zijn dan aangegeven als 1,25 (5,00 gedeeld door 4). Ik ga er vanuit dat de rest van het hout voor een ander project wordt gebruikt

Onderdeel	Winkel	prijs
De Leeuw	Hema	€1,00
Servo 1 type SG90	Ebay.com	€1,60
Servo 2 type S3003	Ebay.com	€3,80
Hout, 3.6mm Triplex	Bouwmarkt	€1,00
Schakelaar, double pole toggle	Ebay.com	€0,80
Microswitch with roller	Ebay.com	€0,13
Batterijclip	Ebay.com	€0,09
Arduino Nano (kloon)	Ebay.com	€2,50
Weerstand 120 ohm	Ebay.com	€0.04
Witte Led	Ebay.com	€0.04
Elco	Ebay.com	€0.20
Schaniertjes	Ebay.com	€0.30
Totaal zonder batterij: € 11,50