Spionage Robot met Arduino

Oktober 2019:
Dit is een leuk project om eens te expirimenteren met een Oled Display op Arduino en communicatie met de Computer.
Deze robot zit boven op de monitor en houdt alles scherp in de gaten. Hij volgt de muis!

Dit project maakt gebruik van een arduino nano en een 128x64 I2c Oled display.
De arduino blijft verbonden met de pc voor voeding en informatie over de muis. Op de pc draait een klein programmatje dat de muis coordinaten doorstuurt.

Onderdelen

Er zijn niet veel onderdelen nodig.
1) De arduino Nano
Deze is bekend (toch?)
Klik op het plaatje voor een link naar een betrouwbare winkel

2) Het Oled Display
Dit is een erg klein display. 0.96 Inch, 128 bij 64 pixels.
Let op dat je de versie koopt met de i2c interface (ook wel iic genoemd), deze heeft 4 pootjes.
En let op dat je niet de variant met twee kleuren koopt! (zie video).

Het Schema

Dit is het schema. In de video bespreek ik het.
Het stelt niets voor, slechts 4 draadjes!

Klik om te vergroten!

3d Prints

Hier is een link naar mijn tinkercad project.

Hier is een zip bestand met alle onderdelen als stl bestanden.

Arduino Sketch

Hier is de arduino sketch (uit de video!) voor de Arduino Nano

// ArduinoSpyingEyes.ino
// www.BartVenneker.nl

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define OLED_RESET 4
Adafruit_SSD1306 display(128, 64, &Wire, OLED_RESET);


char coords[4];
int b, x, y, lastx, lasty ;
unsigned long currentMillis, lastMillis;
unsigned long period = 15000;
bool asleep = false;

void setup() {
  // Set up the display
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);  //try 0x3C or 0x3D
  display.clearDisplay();
  display.setTextColor(WHITE, BLACK);
  display.display();

  lastx = 10;
  lasty = 10;

  // Set up serial
  Serial.begin (57600);
  currentMillis = millis();
  lastMillis = millis();

  // show the angry face!
  faceAngry(0);
}

void loop() {
  coords[0] = 0;
  if (Serial.available()) {
    char c = Serial.read();
    if (c == 'V') {
      Serial.println("Arduino-eyes");
    }

    if (c == 'b') {
      b = 1;
      Serial.readBytes(coords, 3);
    }

    if (c == 'x') {   //xy45
      Serial.readBytes(coords, 3); //y45
      b = 0;
    }
  }

  if (coords[0] == 'y') {
    x = int(coords[1]) - 48 ;
    y = int(coords[2]) - 48 ;

    if ((lastx != x) or (lasty != y) or (b == 1) or true) {
      lastMillis = millis();
      if (asleep) {
        faceAngry(0);
        delay(700);
      }
      asleep = false;
      lastx = x;
      lasty = y;

      if (b == 1) {
        face0(1, y, x);
        delay(100);
      }

      face0(0, y, x);
    }
    b = 0;
  }

  currentMillis = millis();
  if (!asleep and (currentMillis - lastMillis >= period ) ) {
    asleep = true;
    faceSleep();
  }
}

void faceSleep() {

  // face when sleeping!

  faceframe();
  // left eye
  display.drawCircle(44, 34, 16, WHITE);
  display.drawCircle(44, 34, 15, WHITE);
  display.drawCircle(44, 34, 14, WHITE);
  // right eye
  display.drawCircle(89, 34, 16, WHITE);
  display.drawCircle(89, 34, 15, WHITE);
  display.drawCircle(89, 34, 14, WHITE);
  display.fillRect(16, 16, 90, 18, BLACK);
  // left brow
  display.drawLine(29, 16, 49, 10, WHITE);
  display.drawLine(29, 17, 49, 11, WHITE);
  display.drawLine(29, 18, 49, 12, WHITE);
  // right brow
  display.drawLine(84, 10, 104, 16, WHITE);
  display.drawLine(84, 11, 104, 17, WHITE);
  display.drawLine(84, 12, 104, 18, WHITE);

  display.display();
}

void faceAngry(int b) {
  // Angry face!
  faceframe();
  if (b == 0) {
    // left eye
    display.fillCircle(44, 34, 16, WHITE);
    display.fillCircle(48, 34, 5, BLACK);
    // right eye
    display.fillCircle(89, 34, 16, WHITE);
    display.fillCircle(85, 34, 5, BLACK);
  } else {
    closedLeft(32, 30, 0);
    closedRight(32, 30, 0);
  }
  // left brow
  display.drawLine(43, 6, 62, 17, WHITE);
  display.drawLine(43, 7, 62, 18, WHITE);
  display.drawLine(43, 8, 62, 19, WHITE);
  // right brow
  display.drawLine(70, 17, 89, 6, WHITE);
  display.drawLine(70, 18, 89, 7, WHITE);
  display.drawLine(70, 19, 89, 8, WHITE);

  display.display();
}

void face0(int b, int c , int d) {

  int py, px , px1, py1;
  py = map(c, 2, 9, 35, 49);
  py1 = map(c, 4, 9, 35, 40);
  if (py1 < 34) py1 = 34;
  px = map(d, 0, 9, 17, 70);
  px1 = map(d, 0, 9, 28, 58);

  // face
  faceframe();
  if (b == 0) {

    // left eye
    if (c >= 6 and d <= 2)
      display.fillRoundRect(px1 - 14, 36, 30, 16, 16, WHITE);
    else
      display.fillCircle(px1, py1, 16, WHITE);
    display.fillCircle(px, py, 5, BLACK);


    // right eye
    if (c >= 6 and d > 6)
      display.fillRoundRect(px1 + 28, 38, 30, 16, 16, WHITE);
    else
      display.fillCircle(px1 + 45, py1, 16, WHITE);
    display.fillCircle(px + 45, py, 5, BLACK);
  } else {
    if (c >= 6 and d <= 2) {
      // closed eyes bottom left
      closedLeft(20, 30, 5);
      closedRight(20, 30, 0);
    } else if (c >= 6 and d > 6) {
      // closed eys bottom right
      closedLeft(46, 30, 0);
      closedRight(46, 30, 5);
    }
    else {
      // normal closed eyes
      closedLeft(px1 - 4, 30, 0);
      closedRight(px1 - 4, 30, 0);
    }
  }

  if (c >= 6 and d <= 2) {
    // special brows bottom left
    // left brow
    display.drawLine(px1 - 14, 19, px1 + 6, 21, WHITE);
    display.drawLine(px1 - 14, 20, px1 + 6, 22, WHITE);
    display.drawLine(px1 - 14, 21, px1 + 6, 23, WHITE);
    // right brow

    display.drawLine(px1 + 30, 14, px1 + 44, 8, WHITE);
    display.drawLine(px1 + 30, 15, px1 + 44, 9, WHITE);
    display.drawLine(px1 + 30, 16, px1 + 44, 10, WHITE);
    display.drawLine(px1 + 44, 8, px1 + 51, 16 , WHITE);
    display.drawLine(px1 + 43, 8, px1 + 52, 16 , WHITE);
    display.drawLine(px1 + 42, 8, px1 + 53, 16 , WHITE);
    // display the data now
    display.display();
    return;
  }
  if (c >= 6 and d > 6) {
    // special brows bottom right
    // right brow
    display.drawLine(px1 + 50, 26, px1 + 30, 20, WHITE);
    display.drawLine(px1 + 50, 27, px1 + 30, 21, WHITE);
    display.drawLine(px1 + 50, 28, px1 + 30, 22, WHITE);
    // left brow
    //px=px-10;
    display.drawLine(px - 10, 12, px + 4, 18, WHITE);
    display.drawLine(px - 10, 13, px + 4, 19, WHITE);
    display.drawLine(px - 10, 14, px + 4, 20, WHITE);
    display.drawLine(px - 20, 16, px - 10, 12, WHITE);
    display.drawLine(px - 19, 16, px - 9, 12, WHITE);
    display.drawLine(px - 18, 16, px - 8, 12, WHITE);

    // display the data now
    display.display();
    return;
  }


  // normal left brow
  display.drawLine(px1 - 8, py1 - 28, px1 + 12, py1 - 24, WHITE);
  display.drawLine(px1 - 8, py1 - 27, px1 + 12, py1 - 23, WHITE);
  display.drawLine(px1 - 8, py1 - 26, px1 + 12, py1 - 22, WHITE);
  // normal right brow
  display.drawLine(px1 + 34, py1 - 19, px1 + 53, py1 - 25, WHITE);
  display.drawLine(px1 + 34, py1 - 18, px1 + 53, py1 - 24, WHITE);
  display.drawLine(px1 + 34, py1 - 17, px1 + 53, py1 - 23, WHITE);

  // display the data now
  display.display();

}

void faceframe() {
  display.clearDisplay();
  display.drawRoundRect(9, 1, 116, 63, 12, WHITE);
  display.drawRoundRect(10, 2, 114, 61, 12, WHITE);
  display.drawRoundRect(11, 3, 112, 59, 11, WHITE);
}


void closedLeft(int left, int h1, int h2) {
  h1 = h1 + h2;
  display.drawLine(left, h1, left + 23, 40, WHITE);
  display.drawLine(left, h1 + 1, left + 23, 41, WHITE);
  display.drawLine(left, h1 + 2, left + 23, 42, WHITE);
  h1 = h1 - h2 - h2;
  display.drawLine(left, h1 + 20, left + 23, 40, WHITE);
  display.drawLine(left, h1 + 21, left + 23, 41, WHITE);
  display.drawLine(left, h1 + 22, left + 23, 42, WHITE);

}

void closedRight(int left, int h1, int h2) {
  h1 = h1 + h2;
  display.drawLine(left + 33, 41, left + 55, h1, WHITE);
  display.drawLine(left + 33, 41, left + 55, h1 + 1, WHITE);
  display.drawLine(left + 33, 42, left + 55, h1 + 2, WHITE);
  h1 = h1 - h2 - h2;
  display.drawLine(left + 33, 40, left + 55, h1 + 20, WHITE);
  display.drawLine(left + 33, 41, left + 55, h1 + 21, WHITE);
  display.drawLine(left + 33, 42, left + 55, h1 + 22, WHITE);
}

PC Software

Hier is een download link voor het Python Script

Hier is een download link voor het Windows Programma

Hier is een download link voor het VB.NET project (de source code van het Windows programma)

De Video

Kijk, like en subscribe!

Projecten van derden

Koen Velleman maakte zijn eigen versie van deze robot en hij maakte er een mooi artikel over op Thingiverse. Hier is de link:

Wim Labree heeft een RGB led in de buik van de robot aangebracht, dit is een erg leuk effect en geeft het 'ventilatie rooster' meer functie.
Wims Robot