Besturing over Internet

Arduino als internet client

Hoe kun je een Arduino gebruiken om iets te besturen via het Internet?
In dit artikel leg ik uit hoe je dat kunt doen. Maar!... let op! ... Als je op zoek bent naar home automation of domotica, dan zou ik eerst eens kijken naar de Rasberry Pi. Voor dat platform zijn hele mooie oplossingen te krijgen die volgens mij een stuk eenvoudiger zijn om te automatiseren. De Rasberry Pi 3 heeft standaard netwerk (bekabeld) en WiFi, dat maakt het erg makkelijk.

Scope van dit project

We gaan het dus niet hebben over volledige home automation.
Ik ga je laten zien hoe een Arduino gegevens van internet kan halen en daar iets mee kan doen.
In dit voorbeeld maken we een display die weergeeft hoeveel mensen er op dit moment in de ruimte zijn.

peopleInSpace

Bedraad, Goedkoop en eenvoudig

Eerst kijken we naar een bedrade oplossing, we gebruiken deze module.

De ENC2860 ethernet module is een goedkope oplossing waarmee je arduino projecten aan het netwerk kan verbinden.
Voordelen:
+ Goedkoop
+ Klein
+ Werkt met 5 volt logica (geen 3.3 volt conversie nodig)

Nadelen
- Niet draadloos
- Geen TCP/IP Stack intern (zie tekst hieronder>

Deze heeft geen TCP/IP stack aan boord, dat wil zeggen dat de afhandeling van het netwerk verkeer volledig overgelaten word aan de Arduino. Dat kost behoorlijk wat ruimte in het programmageheugen en ook wat processor kracht.

Display Module

Ik gebruik deze display module:
display

te koop op ebay: LINK

Display Library

Ik gebruik deze Arduino library voor de aansturing:

Sketch 1

De eerste sketch (zie video) gebruikt de seriele monitor en laat het begin en einde van de spakketjes zien
Dit helpt om te analyseren in wel pakket de data zit.
De bron is www.howmanypeopleareinspacerightnow.com

#include <EtherCard.h>

// We are using DHCP and DNS to perform a web client request.
// http://opensource.org/licenses/mit-license.php
// PIN Connections (Using Arduino UNO):
//   VCC -   3.3V
//   GND -    GND
//   SCK - Pin 13
//   SO  - Pin 12
//   SI  - Pin 11
//   CS  - Pin 10
//

// ethernet interface mac address, must be unique on the LAN
static byte macaddress[] = { 0x74,0x69,0x69,0x2D,0x30,0x44 };

byte Ethernet::buffer[700];

const char website[] PROGMEM = "www.howmanypeopleareinspacerightnow.com"; // http://www.howmanypeopleareinspacerightnow.com/space.json

unsigned long timer;
 
void setup () {
  
  Serial.begin(115200);
  
  if (ether.begin(sizeof Ethernet::buffer, macaddress, 10) == 0) 
    Serial.println(F("Failed to access Ethernet controller"));
  
  ether.persistTcpConnection(true);
  
  if (!ether.dhcpSetup())
    Serial.println(F("DHCP failed"));

  ether.printIp("IP:  ", ether.myip);
  ether.printIp("GW:  ", ether.gwip);  
  ether.printIp("DNS: ", ether.dnsip); 

  // use DNS to resolve the website's IP address
  if (!ether.dnsLookup(website)) Serial.println("DNS failed");
    
  ether.printIp("SRV: ", ether.hisip);

}

void loop () {
  
    ether.packetLoop(ether.packetReceive());        
    
    if (millis() > timer  ){ 
      ether.browseUrl(PSTR("/space.json"), "", website, getPacket);    
      timer = millis() + 10000;
    }
}

static void getPacket(byte status, word offset, word packetSize) {
  Ethernet::buffer[offset+packetSize] = '\0';
  Serial.println((char *)(Ethernet::buffer+offset));
  Serial.println(" ---  EINDE PAKKET (" + (String)packetSize +" bytes)---");
  }

Sketch 2

De tweede sketch is het complete project met www.howmanypeopleareinspacerightnow.com als bron.

// Display
#include <TM1637Display.h>
#define CLK 2 // clk pin on display module
#define DIO 3 // dio pin on display module
TM1637Display display(CLK, DIO);

#include <EtherCard.h>
// We are using DHCP and DNS to perform a web client request.
// http://opensource.org/licenses/mit-license.php
// PIN Connections (Using Arduino UNO):
//   VCC -   3.3V
//   GND -    GND
//   SCK - Pin 13
//   SO  - Pin 12
//   SI  - Pin 11
//   CS  - Pin 10
//

// ethernet interface mac address, must be unique on the LAN
static byte macaddress[] = { 0x74,0x69,0x69,0x2D,0x30,0x44 };

byte Ethernet::buffer[700];

int peopleInSpace = 0;

const char website[] PROGMEM = "www.howmanypeopleareinspacerightnow.com"; // http://www.howmanypeopleareinspacerightnow.com/space.json

unsigned long timer;
int interval=5000;
void setup () {
  
  Serial.begin(115200);
  
  if (ether.begin(sizeof Ethernet::buffer, macaddress, 10) == 0) 
    Serial.println(F("Failed to access Ethernet controller"));
  
  ether.persistTcpConnection(true);
  
  if (!ether.dhcpSetup())
    Serial.println(F("DHCP failed"));

  ether.printIp("IP:  ", ether.myip);
  ether.printIp("GW:  ", ether.gwip);  
  ether.printIp("DNS: ", ether.dnsip); 

  // use DNS to resolve the website's IP address
  if (!ether.dnsLookup(website)) Serial.println("DNS failed");
    
  ether.printIp("SRV: ", ether.hisip);
}

void loop () {
    ether.packetLoop(ether.packetReceive()); 
               
    if (millis() > timer  ){ 
      ether.browseUrl(PSTR("/space.json"), "", website, getPacket);    
      timer = millis() + interval;
      Serial.println(peopleInSpace);      
      display.setBrightness(2);
      display.showNumberDec(peopleInSpace, 0);    
    }
    
        
}

static void getPacket(byte status, word offset, word packetSize) {
  /*
   
   r" : 6,
   "people" : [
   
  */     
  if (strstr(Ethernet::buffer+offset, "\"people\"") != NULL) {    
    int o=0;
    int x=0;
    while (Ethernet::buffer[offset + x]!=','){     
      if (Ethernet::buffer[offset + x] > 47 && Ethernet::buffer[offset + x] < 58) {
        peopleInSpace = o + (int)Ethernet::buffer[offset + x] - 48;        
        o = peopleInSpace * 10; 
      }
      x++; 
    }     
    interval = 5000;    
  }
    
}

Sketch 3

Het ophalen van de data is niet erg dynamisch of intelligent, als het formaat van de bron data een beetje verandert werkt het niet meer.
Daarom vertrouw ik liever op mijn eigen pagina. Ik heb een eigen pagina gemaakt die de data ophaalt vanaf howmanypeopleareinspacerightnow.com en weergeeft in een heel eenvoudig formaat.
Zie http://bartvenneker.nl/Arduino/peopleinspace.php.
De derde sketch is het complete project met http://bartvenneker.nl/Arduino/peopleinspace.php als bron.

// Display
#include <TM1637Display.h>
#define CLK 2 // clk pin on display module
#define DIO 3 // dio pin on display module
TM1637Display display(CLK, DIO);

#include <EtherCard.h>
// We are using DHCP and DNS to perform a web client request.
// http://opensource.org/licenses/mit-license.php
// PIN Connections (Using Arduino UNO):
//   VCC -   3.3V
//   GND -    GND
//   SCK - Pin 13
//   SO  - Pin 12
//   SI  - Pin 11
//   CS  - Pin 10
//

// ethernet interface mac address, must be unique on the LAN
static byte macaddress[] = { 0x74,0x69,0x69,0x2D,0x30,0x44 };

byte Ethernet::buffer[700];

int peopleInSpace = 0;

const char website[] PROGMEM = "www.bartvenneker.nl"; // http://www.bartvenneker.nl/Arduino/peopleinspace.php

unsigned long timer;
int interval=5000;
void setup () {
  
  Serial.begin(115200);
  
  if (ether.begin(sizeof Ethernet::buffer, macaddress, 10) == 0) 
    Serial.println(F("Failed to access Ethernet controller"));
  
  ether.persistTcpConnection(true);
  
  if (!ether.dhcpSetup())
    Serial.println(F("DHCP failed"));

  ether.printIp("IP:  ", ether.myip);
  ether.printIp("GW:  ", ether.gwip);  
  ether.printIp("DNS: ", ether.dnsip); 

  // use DNS to resolve the website's IP address
  if (!ether.dnsLookup(website)) Serial.println("DNS failed");
    
  ether.printIp("SRV: ", ether.hisip);
}

void loop () {
    ether.packetLoop(ether.packetReceive()); 
               
    if (millis() > timer  ){ 
      
      ether.browseUrl(PSTR("/Arduino/peopleinspace.php"), "", website, getPacket);    
      timer = millis() + interval;
      Serial.println(peopleInSpace);      
      display.setBrightness(2);
      display.showNumberDec(peopleInSpace, 0);    
    }
    
        
}
 
static void getPacket(byte status, word offset, word packetSize) {
  /* 
   pis=6;   
  */     
  if (strstr(Ethernet::buffer+offset, "pis=") != NULL) {    
    int o=0;
    int x=0;
    while (Ethernet::buffer[offset + x]!='='){x++;}
    while (Ethernet::buffer[offset + x]!=';'){     
      if (Ethernet::buffer[offset + x] > 47 && Ethernet::buffer[offset + x] < 58) {
        peopleInSpace = o + (int)Ethernet::buffer[offset + x] - 48;        
        o = peopleInSpace * 10; 
      }
      x++; 
    }     
    interval = 30000;    
  }
    
}

Ik heb nog even een eenvoudig front paneeltje gemaakt, van karton.
Hier een foto van het eind produkt (tot nu toe).

De PHP Code

De arduino raadpleegt dus een php pagina op mijn eigen website.
Deze pagina haalt de gevens op van www.howmanypeopleareinspacerightnow.com en geeft die weer in een vereenvoudigde opmaak.
Dit is de php code van die pagina:

<?php
//  get the number of people in space from  /peopleinspace.json
//  Save the number to a local file.
//  If the files last modification time is less that one hour ago, then get the value from file
//  If the file is older, get the value from json and update the file
//
//  Output pis=5;1210;  
//  1210 is the time right now.


// Get the time
date_default_timezone_set("Europe/Amsterdam");
$localtime = localtime();

// declare the cache file
$file = "./piscount.txt";

// get the last modification time of the file
$lastmod = filemtime ( $file );

// calculate the difference between now and the last modification time in seconds
$dif = date_timestamp_get(date_create()) - $lastmod ;

// if the last modification time is more than 3600 seconds, get the value from the url
if ($dif > 3600 ) {
  // set the url
  $url="http://www.howmanypeopleareinspacerightnow.com/peopleinspace.json";

  // get the json content
  $jsontxt=@file_get_contents($url); 

  // Get the number value from the json result
  $count=json_decode($jsontxt,true)["number"]; 
  
  // write the number to the cache file
  file_put_contents($file, $count);  
}

// read the value from the cache file.
$count = file_get_contents($file);

// display the number of people is space
echo "pis=".$count.";";

// display the time
echo str_pad( $localtime[2] ,2,"0",STR_PAD_LEFT) . str_pad( $localtime[1] ,2,"0",STR_PAD_LEFT) . ";\r\n" . "<br>";

?>

Deel 2, Wifi.. Eindelijk draadloos

In deel 2 maak ik dit project opnieuw maar dan draadloos.

Ik maak gebruik van deze ESP2866 wifi serial module.
Hier is een ebay link naar die module: Link

Sketch 1

In de video gebruik ik 2 sketches, dit is de eerste

#include <TM1637Display.h>
#define CLK 2 // clk pin on display module
#define DIO 3 // dio pin on display module
TM1637Display display(CLK, DIO);

#include <SoftwareSerial.h>

SoftwareSerial mySerial(7, 6); // RX, TX

void setup() {
  // Display
  display.setBrightness(2);
  display.showNumberDec(0, 1);
  
  // Serials 
  Serial.begin(9600);
  mySerial.begin(9600);
  
  // Reset Wifi
  sendWiFi("AT+RST",true); 
  delay(10000);
  clearRXbuffer();
}


void loop() {
  int o=0, peopleInSpace=0;
  char cv;
  unsigned long timout; 

  sendWiFi("AT+CIPSTART=\"TCP\",\"bartvenneker.nl\",80", true);
  sendWiFi("AT+CIPSEND=69", true);
  sendWiFi("GET http://www.bartvenneker.nl/Arduino/peopleinspace.php HTTP/1.0", false);
  
  timout=millis() + 5000;
  // read the response from serial
  // Skip until we get the = character
  while (cv!='=' && millis() < timout) {
    if (mySerial.available()) { cv=mySerial.read();}           
    } 
    
  // Get the number of people in space  
  while (cv!=';' && millis() < timout){    
    if (mySerial.available()) {
      cv=mySerial.read();
     // Serial.write(cv);
      if (cv > 47 && cv < 58) {        
        peopleInSpace = o+ cv - 48;
        o=peopleInSpace * 10;        
      }    
    }   
  }
  delay(500);
  clearRXbuffer();
  Serial.println ("+people in space=" + (String)peopleInSpace);  
  display.showNumberDec(peopleInSpace, 0); 
  delay(10000);
  
 }
 
void sendWiFi(String s, bool clearBuffer){
  mySerial.println(s);
  mySerial.println("");
  delay(100);
  if (clearBuffer) clearRXbuffer();
}

void clearRXbuffer(){
  while (mySerial.available()){
      char c = mySerial.read();  
     // Serial.write(c);
      delay(3);
    }
  }


  
  /*
  +IPD,0,194:HTTP/1.1 200 OK
  Date: Tue, 10 Jan 2017 12:52:48 GMT
  Server: Apache/2
  X-Powered-By: PHP/5.5.38
  Vary: User-Agent
  Content-Length: 12
  Connection: close
  Content-Type: text/html

  pis=6;2243; 
  <br>0,CLOSED

  */

Sketch 2

En hier is de tweede,

#include <TM1637Display.h>
#define CLK 2 // clk pin on display module
#define DIO 3 // dio pin on display module
TM1637Display display(CLK, DIO);

#include <SoftwareSerial.h>

SoftwareSerial mySerial(7, 6); // RX, TX

void setup() {
  display.setBrightness(2);

  pinMode(13,OUTPUT);
  digitalWrite(13,LOW);
 
  Serial.begin(9600);
  mySerial.begin(9600);
 
  resetWiFi();
}

void loop() {
 
  int o=0, updateTime=0, peopleInSpace=0;
  char cv;
  unsigned long timout; 
  static int failCounter=0;

  sendWiFi("AT+CIPSTART=\"TCP\",\"bartvenneker.nl\",80", true);
  sendWiFi("AT+CIPSEND=69", true);
  sendWiFi("GET http://www.bartvenneker.nl/Arduino/peopleinspace.php HTTP/1.0", false);
  
  timout=millis() + 5000;

  // Skip until we get the = character
  while (cv!='=' && millis() < timout) {
    if (mySerial.available()) { cv=mySerial.read();}           
    } 
    
  // Get the number of people in space  
  while (cv!=';' && millis() < timout){
    if (mySerial.available()) {
      cv=mySerial.read();
      if (cv > 47 && cv < 58) {        
        peopleInSpace = o+ cv - 48;
        o=peopleInSpace * 10;        
      }    
    }   
  }

  // Get the time
  o=0;
  cv=mySerial.read();
  while (cv!=';' && millis() < timout){
    if (mySerial.available()) {
      cv=mySerial.read();
      if (cv=='=') {o=0;}
      if (cv > 47 && cv < 58) {               
        updateTime = o+ cv - 48;
        o=updateTime * 10;
      }    
    }   
  }
 
  // reset wifi after 5 failed attempts
  if (updateTime==0) {     
    if (failCounter++ > 5) {
      failCounter=0;
      resetWiFi();
      }
    } else failCounter=0;
    
  Serial.println ("people in space=" + (String)peopleInSpace);
  Serial.println ("last updated=" + (String)updateTime);
  
  clearRXbuffer();
  for (int d=0; d<3;d++) {
    display.showNumberDec(peopleInSpace, 0); 
    delay(5000);
    showTime(updateTime); 
    delay(5000);
  }
 }
 
void sendWiFi(String s, bool clearBuffer){
  mySerial.println(s);
  mySerial.println("");
  delay(100);
 
  if (clearBuffer) clearRXbuffer();
}

void clearRXbuffer(){
  while (mySerial.available()){
      char c = mySerial.read();  
      delay(3);
    }
  }

void showTime(int t){
  display.showNumberDec(t,true);
  uint8_t segto;
  segto = 0x80 | display.encodeDigit((t/ 100)%10);
  display.setSegments(&segto, 1, 1); 
  }


void displayLoop(int q){
  uint8_t data[] = {0x0,0x0,0x0,0x0};
  switch (q) {
    case 0: data[3]=SEG_D; break;
    case 1: data[2]=SEG_D; break;
    case 2: data[1]=SEG_D; break;
    case 3: data[0]=SEG_D; break;
    case 4: data[0]=SEG_E; break;
    case 5: data[0]=SEG_F; break;
    case 6: data[0]=SEG_A; break;
    case 7: data[1]=SEG_A; break;
    case 8: data[2]=SEG_A; break;
    case 9: data[3]=SEG_A; break;
    case 10: data[3]=SEG_B; break;
    case 11: data[3]=SEG_C; break;  
  }
display.setSegments(data);
delay(20);
}

void resetWiFi(){
  
  unsigned long timout=0 ;   
  digitalWrite(13,LOW);  
  Serial.println ("WiFi Reset ");
  // Wait for an IP address (WIFI GOT IP)
  char c, buffer[25];
  int i=0, w=0;
  
  do{
    if (millis() > timout){
      clearRXbuffer();
      timout=millis() + 20000;      
      delay(1000);
      sendWiFi("AT+RST",true); 
    }
    
    if (mySerial.available()) {
      c= mySerial.read();    
      if (c=='W' || i>=20) i=0;
      if (c>9 && c<91){
        buffer[i++]=c;          
        }
    } else displayLoop(w++);
    
    if (w>11) w=0;
    
  } while(strstr(buffer,"WIFI GOT IP")==NULL);
   
  digitalWrite(13,HIGH);  
}

/*
  AT+RST
   
  
  AT+CIPSTART="TCP","bartvenneker.nl",80
  AT+CIPSEND=69
  GET http://www.bartvenneker.nl/Arduino/peopleinspace.php HTTP/1.0
  /*
  +IPD,0,194:HTTP/1.1 200 OK
  Date: Tue, 10 Jan 2017 12:52:48 GMT
  Server: Apache/2
  X-Powered-By: PHP/5.5.38
  Vary: User-Agent
  Content-Length: 12
  Connection: close
  Content-Type: text/html

  pis=6;2243; 
  <br>0,CLOSED

  */

AT Commandos

Voor een volledige lijst met commando verwijs ik je graag de ESP8266 documentatie:

In de video gebruik ik de volgende commandos

Commando	Uitleg
AT+RST	Reset de module
AT+UART_DEF=9600,8,1,0,0	Configureer de module om te communiceren op 9600 baud, 8 databits, 1 stop bit, geen parity en geen flow controll LET OP: Gerbuik geen spaties in dit commando
AT+CWMODE=n	n=1 : Station mode (client) [deze gebruik ik] n=2 : AP Mode (Server) n=3 : Beide
AT+CWLAP	Geeft een lijst met wifi netwerken in de omgeving
AT+CWJAP="ssid","password"	Aanmelden bij netwerk. ssid is de netwerknaam, password is het wachtwoord
AT+CWQAP	Afmelden bij een netwerk
AT+CIPSTART="TCP","bartvenneker.nl",80	Zet een TCP verbinding op met host bartvenneker.nl op poort 80
AT+CIPSEND=69	Stuur 69 bytes aan data in de nnu volgende tekst
GET http://www.bartvenneker.nl/Arduino/peopleinspace.php HTTP/1.0

Deel 3, sd Card reader voor configuratie

Wat nu als het wachtwoord of de ssid naam van de wifi veranderd? Dan moet je de wifi module opnieuw kunnen configureren.
Om dat mogelijk te maken koppelen we een sd card reader aan de arduino.
Bekijk de video!
voor de duidelijkheid: die sd card is dus slechts tijdelijk nodig, alleen om de module te configureren. Daarna mag je de sd card weer voor andere dingen gebruiken.

Sketch in deze video

#include <TM1637Display.h>
#define CLK 2 // clk pin on display module
#define DIO 3 // dio pin on display module
TM1637Display display(CLK, DIO);

#include <SPI.h>
#include <SD.h>
#define SD_CS 8

#include <SoftwareSerial.h>

SoftwareSerial mySerial(7, 6); // RX, TX

void setup() {
  display.setBrightness(2);

  pinMode(13,OUTPUT);
  digitalWrite(13,LOW);
 
  Serial.begin(9600);
  mySerial.begin(9600);
  if (!reconfigureWifi()) resetWiFi();
}

void loop() {
 
  int o=0, updateTime=0, peopleInSpace=0, dl=3;
  char cv;
  unsigned long timout; 
  static int failCounter=0;  
   
  sendWiFi("AT+CIPSTART=\"TCP\",\"bartvenneker.nl\",80", true);
  sendWiFi("AT+CIPSEND=69", true);
  sendWiFi("GET http://www.bartvenneker.nl/Arduino/peopleinspace.php HTTP/1.0", false);

  timout=millis() + 9000;
  
  // Skip until we get the = character
  while (cv!='=' && millis() < timout) {
    if (mySerial.available()) { cv=mySerial.read();}           
    } 
    
  // Get the number of people in space  
  o=0;
  while (cv!=';' && millis() < timout){
    if (mySerial.available()) {
      cv=mySerial.read();
      if (cv=='=') {o=0;}
      if (cv > 47 && cv < 58) {        
        peopleInSpace = o+ cv - 48;
        o=peopleInSpace * 10;        
      }    
    }   
  }

  // Get the time
  o=0;
  cv=mySerial.read();
  while (cv!=';' && millis() < timout){
    if (mySerial.available()) {
      cv=mySerial.read();
      if (cv=='=') {o=0;}      
      if (cv > 47 && cv < 58) {               
        updateTime = o+ cv - 48;
        o=updateTime * 10;
      }    
    }   
  }
 
  // reset wifi after 5 failed attempts
  if (updateTime==0) {     
    if (failCounter++ > 5) {
      failCounter=0;
      resetWiFi();
      dl=1;
      }
    } else {failCounter=0;}
    
  Serial.println ("");  
  Serial.println ("people in space=" + (String)peopleInSpace);
  Serial.println ("last updated=" + (String)updateTime);
  
  clearRXbuffer();
  
  for (int d=0; d<dl;d++) {

    display.showNumberDec(peopleInSpace, 0); 
    delay(5000);

    showTime(updateTime); 
    delay(5000);
    
  }
 }
 
void sendWiFi(String s, bool clearBuffer){
  mySerial.println(s);
  mySerial.println("");
  delay(100);
 
  if (clearBuffer) clearRXbuffer();
}

void clearRXbuffer(){
  while (mySerial.available()){
      char c = mySerial.read();  
      Serial.print(c);
      delay(3);
    }
  }

void showTime(int t){
  display.showNumberDec(t,true);
  uint8_t segto;
  segto = 0x80 | display.encodeDigit((t/ 100)%10);
  display.setSegments(&segto, 1, 1); 
  }


void displayLoop(int q){
  uint8_t data[] = {0x0,0x0,0x0,0x0};
  switch (q) {
    case 0: data[3]=SEG_D; break;
    case 1: data[2]=SEG_D; break;
    case 2: data[1]=SEG_D; break;
    case 3: data[0]=SEG_D; break;
    case 4: data[0]=SEG_E; break;
    case 5: data[0]=SEG_F; break;
    case 6: data[0]=SEG_A; break;
    case 7: data[1]=SEG_A; break;
    case 8: data[2]=SEG_A; break;
    case 9: data[3]=SEG_A; break;
    case 10: data[3]=SEG_B; break;
    case 11: data[3]=SEG_C; break;  
  }
display.setSegments(data);
delay(20);
}

void resetWiFi(){  
  unsigned long timout=0 ;   
  digitalWrite(13,LOW);  
  Serial.println ("WiFi Reset ");
  do{
     clearRXbuffer();
     sendWiFi("AT+RST",true);         
  } while(!waitForIp());
   
  digitalWrite(13,HIGH);  
}

bool waitForIp(){
  unsigned long timout;
  char c;
  char buffer[25];
  int i,w=0;
  timout=millis() + 20000;
  do{
    if (millis() > timout){
      clearRXbuffer();
      timout=millis() + 20000;      
      delay(1000);
      sendWiFi("AT+RST",true); 
    }
    
    if (mySerial.available()) {
      c= mySerial.read();  
      Serial.print(c);  
      if (c=='W' || i>=20) i=0;
      if (c>9 && c<91){
        buffer[i++]=c;          
        }
    } else displayLoop(w++);
    
    if (w>11) w=0;
    
    if (strstr(buffer,"WIFI GOT IP")!=NULL) return true;
  } while(millis() < timout);
  return false;
  }


bool reconfigureWifi() {
  File myFile;
  char c;
  char lineBuffer[80];
  char ssid[25];
  char password[25];
  int i=0;

  if (!SD.begin(SD_CS)) return false; // No SD Card found, exit!
  
  if (!SD.exists("WIFI.TXT") ){
    myFile = SD.open("WIFI.TXT", FILE_WRITE);
    myFile.println("ssid,password");
    myFile.close();
    return false; // SD card found but config file did not exist, exit!
    } 
    
  Serial.println("Reconfigure !"); 
  // read the file, get the ssid and password
  myFile = SD.open("WIFI.TXT");              
  while (myFile.available()) {
    c=myFile.read();
    if (c>=32 && c<127) lineBuffer[i]=c;
    if (c==','){
      lineBuffer[i]='\0';
      strcpy(ssid,lineBuffer); 
      i=-1;       
    }
    if (c== 13) break; // break out the while loop on end of line
    i++;
  } 
  lineBuffer[i]='\0';
  strcpy(password,lineBuffer); 
  myFile.close();   // close the file:
  
  Serial.println(ssid);   
  Serial.println(password); 
  
  sprintf(lineBuffer,"AT+CWJAP=\"%s\",\"%s\"",ssid,password); 
  
  do {
    clearRXbuffer();    
    sendWiFi(lineBuffer,true); // send AT+CWJAP="ssid","password"
  } while (!waitForIp());
        
  return true;
}

Update, september 2017

Mijn website is door mijn provider verplaatst naar een andere server (in een ander datacentrum zelfs), lang verhaal kort: de response die arduino krijgt is nu een beetje anders waardoor mijn code niet helemaal goed meer werkte,
Om dat op te lossen heb ik de volgende regel toegevoegd in de code (zoek het maar op in de code hierboven)
if (cv=='=') {o=0;}

Update, mei 2018

Ik heb de bovenstaande Arduino sketch en de PHP code (ergens halverwege de pagina) ge-update.