Bestuur een bluetooth auto met een Smart Phone!

Als je een klein beetje ervaring hebt met Arduino en eenvoudige elektronica is dit een heel leuk project.
We bouwen een auto (of tank) die je kunt besturen vanaf je Android Smartphone!
Als je nog niet zo veel ervaring hebt met Arduino verwijs ik je graag naar deze Arduino voor Beginners Pagina van Conrad
Hier wordt duidelijk uitgelegd hoe je kunt beginnen met deze leuke hobby en kun je inspiratie vinden voor wat eenvoudige projecten.

Het onderstel

Ik gebruik het volgende onderstel
Het is het Arexx Robby RP5 robotonderstel van Conrad, het heeft 2 ingebouwde motoren en krachtige rupsbanden. Hij wordt geleverd met een batterijvakje voor 6 batterijen voor een totale spanning van 9 volt.

hier is een link naar waar je dit onderstel kunt kopen.

De motorcontroller

Om de twee motoren van het onderstel aan te sturen hebben we een motorcontroller nodig.
Ik gebruik deze, de L298N motor controller voor Arduino

Je kunt deze kopen in verschillende webshops, ik kocht de mijne op ebay voor 2 euro (begin 2016).
Gebruik de zoekterm: motor controller L298N Arduino op ebay en je zult er genoeg vinden.

De motorcontroller aansluiten

In de tekening hieronder zie je hoe de batterijen (9 volt), de schakelaar en de motorcontroller worden aangesloten op Arduino (klik om te vergroten)

Je ziet dat we de 5 volt aansluiting van de motorcontroller niet aansluiten, dat is geen foutje, dat hoort zo.

De bluetooth module

De Bluetooth module die ik gebruik is de HC-06 slave voor Arduino.
Met deze module is het erg eenvoudig om bluetooth besturing toe te voegen aan je Arduino project.
Je koopt deze module bijvoorbeeld op ebay. Hier is een link

De bluetooth module aansluiten

De HC-06 slave module hoeft niet geconfigureerd te worden. Hij kan vanuit de verpakking rechtstreeks het project in.
De bluetooth module is aangesloten op pin 2 en 3 van Arduino, de sketch maakt gebruik van een Softserial verbinding zodat we, indien nodig, de hardware Serial kunnen gebruik voor debugging.

Let wel even op de twee weerstanden in de TX lijn. De HC-06 maakt gebruik van 3.3 volt signalen, de Arduino geeft 5 volt signalen af, we hebben dus die twee weerstanden nodig om het 5 volt signaal af te zwakken tot 3.3 volt.

De Arduino Sketch

Als de motorcontroller en de bluetooth module zijn aangesloten kun je de Arduino sketch gebruiken om de eerste proefrit te maken.
Dit is de sketch die ik ook in de video heb gebruikt

//
// Bart Venneker 2016
// Bluetooth RC Car
// see http://www.bartvenneker.nl/Arduino/index.php?art=0020 for details
// released into the public domain
//
#include <SoftwareSerial.h>
#define L298N_IN1 7
#define L298N_IN2 6
#define L298N_IN3 5
#define L298N_IN4 4
#define horn 8
#define lightFront 9
#define lightRear 10
#define blinkerRight 11
#define blinkerLeft 12

// Use softserial so we can use the hardware serial for debugging if needed
SoftwareSerial mySerial(2, 3); // RX, TX

void setup() {
  pinMode(blinkerLeft,OUTPUT);
  pinMode(blinkerRight,OUTPUT);
  pinMode(lightFront,OUTPUT);
  pinMode(lightRear,OUTPUT);
  pinMode(horn,OUTPUT);
  pinMode(L298N_IN1,OUTPUT);
  pinMode(L298N_IN2,OUTPUT);
  pinMode(L298N_IN3,OUTPUT);
  pinMode(L298N_IN4,OUTPUT); 

  mySerial.begin(9600);
  tone(horn,1000);delay(60);
  tone(horn,800);delay(80);
  noTone(horn);
 }

// Global variables
int dta=0;
int freq;
unsigned long blinkTimer = millis();
unsigned long sireneTimer = millis();
boolean blinker = true;
boolean alarmLights = false;
boolean blinkLeft;
boolean blinkRight;
boolean sirene=false;

void loop() {
  
  // read all data from the serial buffer
  while(mySerial.available() > 0){ 
      int a = mySerial.read() ;    
      if ( a > 13 ) dta = a;   // ignore the carriage return character
      delay(2);                // wait for more data
    }
  
  switch (dta) {
    case 'S':    
      driveTracks(0,0,0,0); setBlinker(0,0); break; // STOP the car
    case 'F':
      driveTracks(0,1,0,1); setBlinker(0,0); break; // Forward
    case 'B':
      driveTracks(1,0,1,0); setBlinker(0,0); break; // Reverse
    case 'L':
      driveTracks(1,0,0,1); setBlinker(0,1); break; // Left
    case 'R': 
      driveTracks(0,1,1,0); setBlinker(1,0); break; // Right
    case 'G':
      driveTracks(0,0,0,1); setBlinker(0,1); break; // Forward and Left
    case 'I':
      driveTracks(0,1,0,0); setBlinker(1,0); break; // Forward and Right
    case 'H':  
      driveTracks(0,0,1,0); setBlinker(0,1); break; // Backward and Left
    case 'J':    
      driveTracks(1,0,0,0); setBlinker(1,0); break; // Backward and Right
    case 'V':    
      sirene=true; break;                           // Sirene on
    case 'v':
      sirene=false; break;                          // Sirene off
    case 'W':
      digitalWrite(lightFront,1); break;            // Head lights on
    case 'w':
      digitalWrite(lightFront,0); break;            // Head lights off
    case 'U':
      digitalWrite(lightRear,1); break;             // Rear lights on
    case 'u':
      digitalWrite(lightRear,0); break;             // Rear lights off
    case 'X':
      alarmLights = true; break;                    // Warning lights on
    case 'x':
      alarmLights = false; break;                   // Warning lights off    
  }
  
  // This is to control the blinking speed, and drive the blinker lights
  if (millis()-blinkTimer > 250) {
    blinkTimer = millis(); 
    blinker = !blinker;    
    if (blinkLeft  | alarmLights) digitalWrite(blinkerLeft,blinker);
    else digitalWrite( blinkerLeft,LOW);
    if (blinkRight | alarmLights) digitalWrite( blinkerRight,blinker);
    else digitalWrite( blinkerRight,LOW);
  }

  // This is to control the sirene 
  if (millis()- sireneTimer > 400) {
    sireneTimer=millis();
    if (freq==700) freq=1000;
    else {freq=700; noTone(horn);}
    if (sirene)  tone(horn,freq);
    }
}

void driveTracks(bool IN1,bool IN2,bool IN3,bool IN4) {
  digitalWrite(L298N_IN1,IN1);
  digitalWrite(L298N_IN2,IN2);
  digitalWrite(L298N_IN3,IN3);
  digitalWrite(L298N_IN4,IN4);   
}

void setBlinker(bool Right,bool Left){
  blinkLeft  =  Left;
  blinkRight =  Right;
}

De Android App

De app die ik gebruik heet Bluetooth RC CAR app van Andi.co. Je vindt de app in de play store.
Ik heb de app getest op een Samsung Galaxy tab 4 en een Sony Xperia E4 telefoon, beide werkte prima.
Om de app met de auto te verbinden heb je soms wel 4 pogingen nodig maar als de verbinding eenmaal tot stand is gekomen is werkt het perfect. De verbinding valt nooit zomaar spontaan weg.

Uitbreidingen

Met alle informatie hierboven kun je een rijdende tank maken. Maar we kunnen nog een paar uitbreidingen doen.

Verlichting

De software en de Arduino sketch ondersteunen koplampen, achterlichten en knipperlichten
In mijn tank heb ik verschillende kleuren Leds gebruikt, witte 5mm leds voor de koplampen, rode 3mm leds voor de achterlichten en oranje 3mm leds voor de knipperlichten.
In de afbeelding hieronder zie je hoe de verlichting is aangesloten.

Sirene

Een laatste leuke toevoeging is de sirene. De software en de Arduino sketch ondersteunen dit al dus je hoeft alleen nog maar een klein luidsprekertje aan te sluiten.
De luidspreker word aangesloten op pin 8 en ground (zie afbeelding hieronder)

Heb jij hem ook gebouwd??

Heb jij dit project ook gebouwd? Of heb je je eigen draai eraan gegeven? Dan ontvang ik graag een foto of een link naar een filmpje om hier op deze website te plaatsen. Dat geeft ook andere bouwers de overtuiging dat zij het ook kunnen!.
Dus als je fotos hebt van jouw project, stuur ze dan naar b.venneker@gmail.com.

Lijst met alle onderdelen

Hier is de lijst met onderdelen, met links naar waar je ze kan kopen:
- Een Arexx Robby RP5 Robot onderstel
- Een Arduino Nano of een clone
- Een Bluetooth HC-06 slave module
- Een Motor controller: motor controller L298N Arduino
- Een aantal weerstanden (4k7, 8k2, 2x 68ohm, 3x 120 ohm, alles 0,25 watt), tip voor beginners: koop een assortiment
- Een aantal ledjes (2x 5mm Witte leds, 2x 3mm rode leds, 4x 3mm gele of oranje leds)
- Een schakelaar
- Een kleine luidspreker of deze
- Dun soepel Draad
- Een Android telefoon of tablet met de Bluetooth RC CAR app
- 5mm triplex uit de bouwmarkt
- Schroefjes, in de video gebruik ik 2.9mm x 13mm plaatschroef, ook te koop bij Hornbach
- een strip 2.54mm Header

De Video

Bekijk de video voor meer informatie!

Projecten van kijkers

Harry bouwde ook een bluetooth tank naar aanleiding van dit ontwerp.
Harrys Tank

Hij maakt een video van het resultaat zodat wij er ook van kunnen genieten.

Link naar Harry's website met meer projecten: http://halfzwaar.nl