Bestuur een Arduino Met je Smart Phone!

Hoe kun je een arduino project besturen vanaf je Smart Phone?
In andere projecten heb ik gebruik gemaakt van een infra rood afstandsbediening om een Arduino te besturen. Ik gebruikte bijvoorbeeld deze:

Maar het is ook heel eenvoudig om je Android Smart Phone te gebruiken als eenvoudige afstandsbediening!

Wat heb je nodig?

- Een Arduino
- Een Bluetooth module, bijvoorbeeld de HC-06 (zie afbeelding hieronder)
- Een Android telefoon of tablet met de easy remote app (zie afbeelding hieronder)

Dit is de bluetooth module die ik gebruik

hier is een afbeelding van de app op android die ik gebruik, er bestaan veel meer van dit soort apps, je zou ook een ander kunnen gebruiken.
In de video onderaan deze pagina leg ik uit hoe je de app configureer.

De bluetooth module aansluiten

De bluetooh module is aangesloten op pin 2 en 3, we maken straks gebruik van een Softserial verbinding zodat we de hardware UART kunnen gebruik voor debugging
Als alles goed werkt kun je natuurlijk ook de bluetooth module aansluiten op de pin 0 en 1 en gewoon de hardware serial gebruiken.

Let ook even op de twee weerstanden in de TX lijn. De HC-06 maakt gebruik van 3.3 volt signalen, de arduino geeft 5 volt signalen af, we hebben dus die twee weerstanden nodig om het 5 volt signaal af te zwakken tot 3.3 volt.

De Arduino Sketch

In de video laat ik zien hoe je de afstandsbediening configureer en wat je er mee kunt doen.
In de video gebruik ik de volgende sketch

#include <SoftwareSerial.h>
#include <Servo.h>

#define speaker 6

SoftwareSerial mySerial(2, 3); // RX, TX
Servo myServo;

void setup() {
  // put your setup code here, to run once:
  mySerial.begin(9600); // for communication with the bluetooth module
  Serial.begin(9600);   // for communication with PC during debugging
  pinMode(12,OUTPUT);  // LED
  pinMode(8,OUTPUT);   // Relay
  myServo.attach(7,700,2700); // attach a tower pro g9 micro servo on pin 7
}

char i;
String signal;
int servoPos=90;
bool relay=false;

void loop() {

  signal="";
  // Wait for serial data
  while(mySerial.available() > 0){     
      signal += (char)mySerial.read();   
      delay(2);
  }

  // print out the soft serial data to the Uart serial for debugging
  if (signal != "" )Serial.println(signal);


  // Control a led
  if (signal=="1") {
    digitalWrite(12,HIGH);
    }  
  if (signal=="2") {
    digitalWrite(12,LOW);
    }

  // Controll a servo
  if (signal== "13") {servoPos+=10;}
  if (signal== "16") {servoPos-=10;}
  if (signal== "14") {servoPos=90;}
  // write the servo position
  if (servoPos<0) servoPos=0;
  if (servoPos>180) servoPos=180;
  myServo.write(servoPos);


  // Play a sound
  if (signal=="3") {
    // Play the ding dong sound
    tone(speaker, 1000);//Speaker on 
    delay(200);
    tone(speaker, 800); //Speaker on 
    delay(450);
    noTone(speaker);   // Speaker off
    }

  // toggle a relay on/off  
  if (signal=="10") {
    relay = !relay;
    digitalWrite(8,relay);
  }

  
}

De Video

Bekijk de video voor meer informatie!